Jeśli chcesz wziąć udział w dyskusjach na forum - zaloguj się. Jeżeli nie masz loginu - poproś o członkostwo.

• Zapomniane hasło?
• Poproś o członkostwo

1. • 1:
      
     CommentAuthorKaz
   • CommentTime10 Nov 2008

    
   Poszukuje jakiegos ciekawego efektu dzwiekowego do gry w Turbo Basicu. No wiecie, jakies SOUND z parametrami i petelka. W konkursowej grze nie wolno uzywac procedur maszynowych, ale jakies skromne udzwiekowienie by sie przydalo.
   
   Pamietam, ze gdzies widzialem przyklady takich odglosow jak syrena karetki pogotowia, strzal, etc. Nie byl to czasem Bajtek?
2. • 2:
      
     CommentAuthorsikor
   • CommentTime10 Nov 2008

    
   Hej!!!
   Nie, to nie był bajtek ;) To była najzwyklejsza instrukcja obsługi do Atari 65XE (i do 130XE) - taka w czerwonej okładce. Nie wiem czy w instrukcji do Atari Basica z Atari 800XL (tam instrukcja do Basica była oddzielnie, o ile pamiętam) też tego nie ma. Może warto także sprawdzić u Miguta (Atari Basic w niebieskiej okładce, a także w czarno-białej kserówce u Ciebie na stronie) ;)
3. • 3:
      
     CommentAuthorKaz
   • CommentTime11 Nov 2008

    
   Programiki z instrukcji pamietam, bo kto ich nie wpisywal? :) A to co szukam moglo byc rzeczywiscie w Migucie, ale nie wiem dlaczego mam nieodparte wrazenie, ze to jednak Bajtek? Poszukam.
4. • 4:
      
     CommentAuthorsikor
   • CommentTime12 Nov 2008

    
   Może i tak - nie będę się spierał, bo nie jestem na 100% pewny... W klanie Atari chyba rzeczywiście też coś było... W każdym razie - powodzonka ;)
5. • 5:
      
     CommentAuthorKaz
   • CommentTime5 Jun 2023 zmieniony

    
   Tak, to było w instrukcji do Atari, tej oryginalnej, amerykańskiej. Ale znalazłem też tutaj: (może się komuś przyda)
   
   ->link<-
   
   (autor: Richard M. Kruse, Xentrix Engineering )
   
   

   LISTING 1: PERCUSSIVE SOUND GENERATOR
   10000 REM PERCUSSIVE SOUND GEN
   10002 REM ENTER W/2 PARAMETERS
   10004 REM NTE=PITCH, 0-255
   10006 REM DUR=LNGTH OF EFFECT, 0-10
   10010 SOUND 1,5,8,6
   10015 VOL=15:ICR=0.79+DUR/50
   10020 SOUND 0,NTE,10,VOL
   10025 SOUND 1,0,0,0
   10030 VOL=VOL*ICR
   10035 IF VOL<1 THEN 10020
   10040 SOUND 0,0,0,0:RETURN
   
   LISTING 2: DOORBELL
   10000 REM DOORBELL
   10002 REM NO ENTRY PARAMETERS
   10010 NTE=105:DUR=7.5:GOSUB 10025
   10015 NTE=132:DUR=8.5:GOSUB 10025
   10020 SOUND 0,0,0,0:RETURN
   10025 VOL=15:ICR=0.79+DUR/50
   10030 SOUND 0,NTE,10,VOL
   10035 VOL=VOL*ICR
   10040 IF VOL>U THEN 10030
   10045 RETURN
   
   LISTING 3: TELEPHONE BELL
   10000 REM TELEPHONE BELL
   10002 REM ONE ENTRY PARAMETER
   10004 REM TMS=* RINGS
   10010 FOR XX=1 TO 35
   10015 IR=0.3:LM=2:GOSUB 10055
   10020 NEXT XX
   10025 IR=0.9:LM=1:GOSUB 10055
   10030 SOUND 0,0,0,0:SOUND 1,0,0,0
   10035 TMS=TMS-1
   10040 IF TMS<1 THEN RETURN
   10045 FOR WT=1 TO 300:NEXT WT
   10050 GOTO 10010
   10055 VL=15
   10060 SOUND 0,40,10,VL
   10065 SOUND 1,42,10,VL
   10070 VL=VL*IR
   10075 IF VL>LM THEN 10060
   10080 RETURN
   
   LISTING 4: ALARM BELL
   10000 REM ALARM BELL
   10002 REM ONE ENTRY PARAMETER
   10004 REM DUR=APPROX SECONDS RUN
   10010 FOR TMS=1 TO DUR*12
   10015 VL=15:IR=0.5:LM=3:GOSUB 10040
   10020 NEXT TMS
   10025 VL=10:IR=0.95:LM=1:GOSUB 10040
   10030 SOUND 0,0,0,0:SOUND 1,0,0,0
   10035 RETURN
   10040 SOUND 0,53,10,VL:SOUND 1,60,10,VL
   10045 VL=VL*IR
   10050 IF VL>LM THEN 10040
   10060 RETURN
   
   LISTING 5: EXPLOSION
   10000 REM EXPLOSION
   10002 REM ONE ENTRY PARAMETER
   10004 REM DUR=LNGTH OF EFFECT, 0-10
   10010 NTE=20:GOSUB 10025
   10015 SOUND 1,0,0,0:SOUND 2,0,0,0
   10020 RETURN
   10025 SOUND 2,75,8,15
   10030 ICR=0.79+DUR/100
   10035 V1=15:V2=15:V3=15
   10040 SOUND 0,NTE,8,V1
   10045 SOUND 1,NTE+20,8,V2
   10050 SOUND 2,NTE+50,8,V3
   10055 V1=V1*ICR
   10060 V2=V2*(ICR+0.05)
   10065 V3=V3*(ICR+0.08)
   10070 IF V3>1 THEN 10040
   10075 SOUND 0,0,0,0:RETURN
   
   LISTING 6: AMERICAN SIREN
   10000 REM SIREN 1
   10002 REM ONE ENTRY PARAMETER
   10004 REM DUR=APPROX SECONDS RUN
   10010 LO=50:HI=35:STP=-1
   10015 FOR TIM=1 TO DUR
   10020 FOR NTE=LO TO HI STEP STP
   10025 SOUND 0,NTE,10,14
   10030 FOR WT=1 TO 22:NEXT WT
   10035 NEXT NTE
   10040 XX=LO:LO=HI:HI=XX:STP=-STP
   10045 NEXT TIM
   10050 SOUND 0,0,0,0:RETURN
   
   LISTING 7: EUROPEAN SIREN
   10000 REM SIREN 2
   10002 REM ONE ENTRY PARAMETER
   10004 REM DUR=APPROX SECONDS RUN
   10010 LO=57:HI=45:NT=HI
   10015 FOR TIM=0 TO DUR*2
   10022 SOUND 0,NT,10,14
   10025 FOR WT=1 TO 180:NEXT WT
   10030 NT=LO:LO=HI:HI=NT
   10035 NEXT TIM
   10040 SOUND 0,0,0,0:RETURN
   
   LISTING 8: TICKING CLOCK
   10000 REM TICKING CLOCK
   10002 REM TWO ENTRY PARAMETERS
   10004 REM SIZ=1(FST) TO 10(SLW)
   10006 REM DUR=APPROX SECONDS AT SIZ 5
   10010 TIC=SIZ+5:TOC=SIZ+10
   10015 FOR TIM=1 TO DUR
   10020 SOUND 0,TIC,8,12:GOSUB 10035
   10025 SOUND 0,TOC,8,12:GOSUB 10035
   10030 NEXT TIM:RETURN
   10035 SOUND 0,0,0,0
   10040 FOR WT=1 TO SIZ*34:NEXT WT
   10045 RETURN
   
   LISTING 9: KLAXON
   10000 REM KLAXON
   10002 REM ONE ENTRY PARAMETER
   10004 REM DUR=APPROX SECONDS RUN
   10010 FOR TIM=1 TO DUR
   10015 FOR NT=1 TO 10
   10020 SOUND 0,100-NT,10,10
   10025 NEXT NT
   10030 SOUND 0,90,10,14
   10035 SOUND 1,95,80,12
   10040 SOUND 2,20,2,4
   10045 FOR WT=1 TO 200:NEXT WT
   10050 SOUND 1,0,0,0:SOUND 2,0,0,0
   10055 FOR NT=1 TO 5
   10060 SOUND 0,90+NT,10,8
   10065 NEXT NT:SOUND 0,0,0,0
   10070 FOR WT=1 TO 100:NEXT WT
   10075 NEXT TIM:RETURN
   
   LISTING 10: WHISTLE AND BOMB
   10000 REM WHISTLE & BOMB
   10002 REM ONE ENTRY PARAMETER
   10004 REM DUR=LNGTH OF EFFECT
   10010 V1=4:FOR NT=30 TO 75
   10015 SOUND 0,NT,10,V1
   10020 SOUND 1,NT+3,10,V1*0.7
   10025 FOR WT=1 TO DUR*3:NEXT WT
   10030 V1=V1*1.03:NEXT NT
   10035 SOUND 2,35,8,12
   10040 V1=15:V2=15:V3=15
   10045 NT=DUR+5:ICR=0.79+DUR/100
   10050 SOUND 0,NT,8,V1
   10055 SOUND 1,NT+20,8,V2
   10060 SOUND 2,NT+50,8,V3
   10065 V1=V1*ICR
   10070 V2=V2*(ICR+0.05)
   10075 V3=V3*(ICR+0.08)
   10080 IF V3>1 THEN 10050
   10085 SOUND 0,0,0,0:SOUND 1,0,0,0
   10090 SOUND 2,0,0,0:RETURN
   
   LISTING 11: STEAM WHISTLE
   10000 REM STEAM WHISTLE
   10002 REM ONE ENTRY PARAMETER
   10004 REM DUR=APPROX SECONDS RUN
   10010 FOR VL=2 TO 14
   10015 SOUND 1,56,10,VL:SOUND 2,66,10,VL
   10020 NEXT VL
   10025 SOUND 1,55,10,14:SOUND 0,5,8,3
   10030 FOR WT=1 TO DUR*400:NEXT WT
   10035 SOUND 0,0,0,0
   10040 FOR VL=14 TO 1 STEP -2
   10045 SOUND 1,55,10,VL:SOUND 2,67,10,VL
   10050 NEXT VL
   10055 FOR WT=1 TO 25:NEXT WT
   10060 SOUND 1,0,0,0:SOUND 2,0,0,0
   10065 RETURN
   
   LISTING 12: SAWING WOOD
   10000 REM SAWING WOOD
   10002 REM ONE ENTRY PARAMETER
   10004 REM DUR=APPROX SECONDS RUN
   10010 FOR TMS=1 TO DUR
   10015 ST=6:VL=12:GOSUB 10030
   10020 ST=8:VL=8:GOSUB 10030
   10025 NEXT TMS:RETURN
   10030 FOR NT=ST+5 TO ST STEP -1
   10035 GOSUB 10065:NEXT NT
   10040 FOR NT=ST TO ST+5
   10045 GOSUB 10065:NEXT NT
   10050 SOUND 0,0,0,0:SOUND 1,0,0,0
   10055 FOR WT=1 TO 25:NEXT WT
   10060 RETURN
   10065 SOUND 0,NT,2,VL
   10070 SOUND 1,NT,8,VL*0.7
   10075 WT=(WT/5)*5:RETURN
6. • 6:
      
     CommentAuthorAlex
   • CommentTime5 Jun 2023

    
   Wywala errory, ale działa :)
7. • 7: CommentAuthortebe
   • CommentTime5 Jun 2023

    
   bo to są fragmenty kodu pomyślane jako podprocedury mające być wywołane przez GOSUB, RETURN na końcu każdej z nich o tym świadczy